Effet néon
La présentation de cet effet se trouve dans le
dossier Les illusions des sens, page 11 - Pour la science HS avril/juin 2003.
u = 2cm;
color c[];
c1 := (0,0.6,0.8);
c2 := (0.8,0.6,0);
vardef cercles (expr x,y,c) =
for i:=1 upto 4:
draw fullcircle scaled ((2+i)*u) shifted (x,y)
withpen pencircle scaled .15u withcolor c;
endfor;
enddef;
path ecran;
ecran := (0,0) .. (4u,-0.9u) .. (8u,0) ..
(8.9u,4u) .. (8u,8u) .. (4u,8.9u) ..
(0,8u) .. (-0.9u,4u) .. cycle;
picture sauvegarde;
L'illusion présentée ici est l' effet néon (Dario Varin, 1971),
je l'ai trouvée à la page 11 du dossier Les illusions des sens
(Pour la science, avril/juin 2003).}
La variation des couleurs suggère une surface ayant la forme d'un
écran et légèrement teintée.
Sa construction avec MetaPost met cette suggestion à l'œuvre
puisque le changement de couleur s'obtient facilement à l'aide d'un
pochoir ayant la forme de cet écran...
beginfig(1);
cercles(0,0,c2);
cercles(0,8u,c2);
cercles(8u,8u,c2);
cercles(8u,0,c2);
clip currentpicture to ecran;
sauvegarde := currentpicture;
currentpicture := nullpicture;
cercles(0,0,c1);
cercles(0,8u,c1);
cercles(8u,8u,c1);
cercles(8u,0,c1);
draw sauvegarde;
endfig;
En supprimant les parties bleues, l'illusion disparaît...
beginfig(2);
cercles(0,0,c2);
cercles(0,8u,c2);
cercles(8u,8u,c2);
cercles(8u,0,c2);
clip currentpicture to ecran;
endfig;
end
|
