%@AUTEUR:Guillaume Connan
prologues:=2;

verbatimtex
%&latex
\documentclass{article}
\usepackage{amssymb}
\begin{document}
etex

input courbes;
input geo;

color vert_e, turquoise, orange, vert_fonce, rose, vert_mer, bleu_ciel, or, rouge_v,bleu_m,bleu,bleu_f;
vert_e:=(0,0.790002,0.340007);
turquoise:=(0.250999,0.878399,0.815699);
orange:=(0.589999,0.269997,0.080004);
vert_fonce:=(0,1.4*0.392193,0);
rose:=(1.0, 0.752907, 0.796106);
bleu_ciel:=(1.2*0.529405,1.2*0.807794,1);%.2*0.921598);
or:=(1,0.843104,0);
rouge_v:=(0.829997,0.099994,0.119999);
bleu_m:=(0.7*0.529405,0.7*0.807794,0.7);%*0.921598);
bleu_f:=(0.211762,0.3231176,0.3686392);
bleu:=(0.529405,0.807794,1);

ux:=1.25cm; uy:=1cm;
xmin := -0.5; xmax := 8;
ymin := xmin; ymax := xmax-1;

beginfig(1);
  
%Axe
  drawarrow (ux*xmin,0) -- ((1.3*xmax)*ux,0) ;% axe des x
  label.rt(btex \large{$\mathbb{R}$} etex,(1.3*xmax*ux,0));

%Points v(n)
  pair v[];
  pair b; %shift vers le bas pour les labels
  
  for i=3 upto 26:
    v[i]=((i/(i+1)-3/4)*6*(xmax-.5)*ux,0);
  endfor;
  b=(0,-.3*uy);
  
  for i=3 upto 24:
    draw v[i] withpen pencircle scaled 4bp;
  endfor;
  for i=18 upto 23:
    draw v[i]shifted (v[17]-v[21]) withpen pencircle scaled 4bp;
  endfor;
  
  label.bot(btex $u_0$ etex, v[3] shifted b);
  label.bot(btex $u_1$ etex, v[4] shifted b);

%Points seuils
  pair y[]; %points seuils
  pair h,hh; %shift vers le haut pour les labels
  path r,rr; %tiret vertical
  
  y[1]=(2v[8]+v[9])/3;
  y[2]=(v[15]+v[16])/2;
  y[3]=v[20]+(0.1*ux,0) ;
  y[4]=v[26]+(0.1*ux,0) ;
  h=(0,.3*uy);hh=(0,uy);
  r=(0,0.15*uy)--(0,-0.15*uy);
  rr=(0,0.85*uy)--(0,-0.85*uy);
  
  draw r shifted y[1] withpen pencircle scaled 1.5bp withcolor bleu_m;
  draw r shifted y[2] withpen pencircle scaled 1.5bp withcolor bleu_m;
  draw r shifted y[4] withpen pencircle scaled 1.5bp withcolor bleu_m;
  draw rr shifted y[3] withpen pencircle scaled 4bp withcolor bleu_m;
  
  label.top(btex $\ell-1$ etex, y[1] shifted h) withcolor bleu_m;
  label.top(btex $\ell-0,1$ etex, y[2] shifted h) withcolor bleu_m;
  label.top(btex $\ell+0,1$ etex, y[4] shifted h) withcolor bleu_m;
  label.top(btex \LARGE{\boldmath$\ell$\unboldmath} etex, y[3] shifted hh) withcolor bleu;
  
endfig;
end