Quelques terminaux de gnuplot

Présentation

À partir de la description d'une figure sous gnuplot, le choix d'un terminal approprié permet d'obtenir un fichier adapté à l'usage ultérieur souhaité. Il existe un grand nombre de terminaux possibles, certains sont liés à des matériels, d'autres à des formats de fichier. Ils acceptent plus ou moins de paramètres de configuration, en particulier le mode pm3d n'est pas configurable pour tous.

La figure utilisée pour la présentation de quelques uns de ces terminaux est une surface.

Fichier : sombrero.gp
set isosamples 50
set hidden3d
splot [-pi:pi] [-pi:pi] sin(x**2+y**2)/(x**2+y**2)
 

Il est possible d'exécuter des commandes extérieures à partir de gnuplot. C'est ce que je fais pour transformer les fichiers images produits. Il est nécessaire de forcer la fermeture de ces fichiers, c'est pour cela que vous verrez set output (sans nom de fichier indiqué) apparaître dans les fichiers sources ci-dessous.

Terminaux basiques

EPS (postscript encapsulé)

Le format EPS est certainement le plus simple à envisager. Le fichier produit par gnuplot est ensuite converti en PDF, l'image présente dans la page provient d'une conversion en PNG.

Fichier : term_eps.gp
set terminal postscript eps color "Times-Roman" 16
set output 'sombrero.eps'
load 'sombrero.gp'
set output
# Appel extérieur à epstopdf pour transformer le fichier eps en pdf.
!epstopdf --outfile=sombrero_eps.pdf sombrero.eps 
quit
 
sombrero-eps.png

MetaPost

Une autre façon, indirecte celle-ci, d'obtenir un fichier PostScript est de demander la production d'un fichier MetaPost. L'avantage de cette méthode réside dans le fait qu'il est possible de retoucher le fichier à la main et cela assez facilement pour qui connaît un peu MetaPost.

Fichier : term_mp.gp
set terminal mp color
set output 'sombrero.mp'
load 'sombrero.gp'
set output
# Appels extérieurs pour transformer le fichier metapost en PDF
!mpost sombrero.mp
!mptopdf sombrero.0
quit
 
sombrero-mp.png

PSTricks

On ne s'écarte pas de postscript, le fichier peut être directement inclu dans un source LaTeX, à la condition que la paquet pstricks.sty soit invoqué dans le préambule de ce dernier.

Fichier : term_pst.gp
set terminal pstricks
set output 'sombrero_pst.pst'
load 'sombrero.gp'
quit
 
sombrero_pst.png

 

Autres terminaux

PNG

Le format PNG permet l'obtention directe d'une image légère pouvant être insérée dans une page HTML.

Fichier : term_png.gp
set terminal png size 450,360 small
set output 'sombrero_png.png'
load 'sombrero.gp'
quit
sombrero_png.png

SVG

SVG est un format plein d'avenir pour la description d'une image. L'affichage, si le navigateur le permet, est très satisfaisant puisqu'on profite alors de l'aspect vectoriel. La taille initiale du fichier peut être importante mais il est possible de le compresser, ce qui représente un gain non négligeable…

Fichier : term_svg.gp
set terminal svg rounded size 450,360
set output 'sombrero.svg'
load 'sombrero.gp'
set output
# Compression
!gzip -S z sombrero.svg
quit